Unable to open window

[vincent-chtln]

🔍 Is there already an issue for your problem?

• I have checked older issues, open and closed

📝 Description

I just updated to latest v7.0.0 version published yesterday (previously on latest 6.x version), and I can no longer open the app window when I click on the tray icon. Nothing happens as well when I right-click on the icon. I have to use the Task Manager to close the app.

It seems the extension still work though, as I received notifications when the app started and the icon is properly colored.

🪜 Steps To Reproduce

Update to 7.0.0 version

🪵 Log Excerpts

No response

Gitify Version

7.0.0

Operating System

Windows

GitHub Account

GitHub Cloud

📸 Screenshots

No response

[iki]

@setchy same for me, some more info:

• happens each time
• killing the process + removing/renaming %AppData%\gitify profile + restarting => new profile is created, no change
• no errors in %AppData%\gitify\logs\main.log, only 2+2 lines for app/auto updater

  [2026-07-23 10:42:47.161] [info]  [app updater] Starting updater
  [2026-07-23 10:42:47.164] [info]  [app updater] Checking for updates on application launch
  [2026-07-23 10:42:47.164] [info]  [auto updater] Checking for update
  [2026-07-23 10:42:48.777] [info]  [auto updater] Update not available

🚑 Workaround: Kill Gitify process, remove update, install Gitify 6.2.0

taskkill /im gitify.exe
del /s /q /f "%LocalAppData%\gitify-updater"
winget uninstall -e --all-versions --id Gitify.Gitify
winget install -e --id Gitify.Gitify --version 6.2.0

[vincent-chtln]

@iki thanks for the complemetary info, my report was a bit thin 😅
Moved back to 6.20.0 too, app works fine.

[danielpof]

Anyone knows how to disable the auto-upgrade? I keep being upgraded to the broken version

[iki]

New v7.0.1 still has the issue

[iki]

Anyone knows how to disable the auto-upgrade? I keep being upgraded to the broken version

@danielpof to disable update via winget (which now has the 7.0.1) just pin the packackage. And to disable autoupdate it helped me to create %LocalAppData%\gitify-updater file, so the updater fails to create its working directory.

Here's the updated v6.2.0 reinstall script:

@echo off

call :log Kill Gitify
tasklist /fi "imagename eq gitify.exe" | findstr /i /b gitify.exe >nul
if not errorlevel 1 call :run taskkill /im gitify.exe || exit /b

call :log Remove Gitify updater
if exist "%LocalAppData%\gitify-updater" call :run del /q /f "%LocalAppData%\gitify-updater" || exit /b
if exist "%LocalAppData%\gitify-updater" call :run rd /s /q "%LocalAppData%\gitify-updater" || exit /b

call :log Disable Gitify updater > "%LocalAppData%\gitify-updater" || exit /b

call :log Uninstall Gitify
call :run winget uninstall -e --all-versions --id Gitify.Gitify
::: Continue if no matching package was fpund (-1978335212)
if not "%errorlevel%"=="-1978335212" if not "%errorlevel%"=="0" exit /b %errorlevel%

call :log Install Gitify 6.2.0
:install
call :run winget install --no-upgrade --silent -e --id Gitify.Gitify --version 6.2.0
::: Retry if no matching package was fpund (-1978335212)
::: - Winget needs few seconds after uninstall tp recognize package as not installed
if "%errorlevel%"=="-1978335212" (goto :install) else if not "%errorlevel%"=="0" exit /b %errorlevel%

call :log Pin Gitify 6.2.0
call :run winget pin add -e --id Gitify.Gitify --version 6.2.0 || exit /b

call :log Run Gitify 6.2.0
::: Actually start /b doesn't work here,
::: gitify launches subprocess and keeps running in the current session anyway
call :run start /b "Gitify 6.2.0" "%LocalAppData%\Programs\Gitify\Gitify.exe"

call :log Done
exit /b 

:log
echo === %*>&2
exit /b

:run
echo ^>^>^> %*>&2
call %*
if not "%errorlevel%"=="0" echo ^<^<^< (%errorlevel%) %*>&2 && exit /b %errorlevel%